.SUBCKT eqvtProbeLoadE5379 %"probeTip" %"GND"
    #
    # REV 18 Jun 2002
    #
    # SAME LOAD MODEL IS USED FOR E5378A and E5379A
    #
    # THIS MODEL IS INTENDED FOR SIMULATING THE EQUIVALENT LOAD ON A USER'S
    # TARGET AND TO SIMULATE THE SIGNAL AT THE LOGIC ANALYZER PROBE TIP.
    # 
    # BASED ON IN-CIRCUIT MEASUREMENTS MADE WITH 8753E 6GHz NETWORK ANALYZER
    #   accurately models probe load out to 6 GHz
    #   including connector resonance
    #   includes mated-pair connector
    #   includes mfr's recommended pad size over 5mil dialectric Er=4.0
    #   spice components are equivalent loads, not actual component values
    #
    # DOES NOT INCLUDE ANY TRACE STUBS ON TARGET

    .param Rtap=121
    .param Rtip=20K
    .param CtipEqvt=0.7p
    .param Reqvt=30
    .param Lcon=3.50n
    .param Ccon_pads=1.5p

    # lumped L-C model of connector and SMT pads
    Cpad1  %'probeTip'   %'GND'  value=0.25pF
    Lcon1  %'probeTip'   %'con1' value=1.6nH
    Ccon2  %'con1'  %'con2' value=1.25pF
    R3     %'con2'  %'GND'  value=3
    Lcon2  %'con1'  %'con3' value=1.9nH

    # eqvt circuit of isolation network and traces
    R2     %'con3'  %'net1'  value=Rtap
    Ctip   %'net1'  %'net2'  value=CtipEqvt
    R4     %'net2'  %'GND'   value=Reqvt
    R5     %'net1'  %'vtrm'  value=Rtip
    Vtrm   %'vtrm'  %'GND'   DC 0.75

.ENDS eqvtProbeLoadE5379